236 lines
8.4 KiB
CMake
236 lines
8.4 KiB
CMake
cmake_minimum_required (VERSION 3.0)
|
|
project (uirc3 VERSION 1.1.0 LANGUAGES C)
|
|
|
|
# Options
|
|
option (WANT_READLINE "Use GNU Readline for the UI (better)" ON)
|
|
option (WANT_LIBEDIT "Use BSD libedit for the UI" OFF)
|
|
|
|
# Moar warnings
|
|
if ("${CMAKE_C_COMPILER_ID}" MATCHES "GNU" OR CMAKE_COMPILER_IS_GNUCC)
|
|
# -Wunused-function is pretty annoying here, as everything is static
|
|
set (wdisabled "-Wno-unused-function")
|
|
set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 -Wall -Wextra ${wdisabled}")
|
|
endif ()
|
|
|
|
# Version
|
|
set (project_version "${PROJECT_VERSION}")
|
|
|
|
# Try to append commit ID if it follows a version tag. It might be nicer if
|
|
# we could also detect dirty worktrees but that's very hard to get right.
|
|
# If we didn't need this for CPack, we could use add_custom_command to generate
|
|
# a version source/include file.
|
|
find_package (Git)
|
|
set (git_head "${PROJECT_SOURCE_DIR}/.git/HEAD")
|
|
if (GIT_FOUND AND EXISTS "${git_head}")
|
|
configure_file ("${git_head}" git-head.tag COPYONLY)
|
|
file (READ "${git_head}" git_head_content)
|
|
if (git_head_content MATCHES "^ref: ([^\r\n]+)")
|
|
set (git_ref "${PROJECT_SOURCE_DIR}/.git/${CMAKE_MATCH_1}")
|
|
if (EXISTS "${git_ref}")
|
|
configure_file ("${git_ref}" git-ref.tag COPYONLY)
|
|
endif ()
|
|
endif ()
|
|
|
|
execute_process (COMMAND ${GIT_EXECUTABLE} describe --tags --match v*
|
|
WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
|
|
RESULT_VARIABLE git_describe_result
|
|
OUTPUT_VARIABLE git_describe OUTPUT_STRIP_TRAILING_WHITESPACE)
|
|
if (NOT git_describe_result)
|
|
string (REGEX REPLACE "^v" "" project_version "${git_describe}")
|
|
endif ()
|
|
endif ()
|
|
|
|
# Dashes make filenames confusing and upset packaging software
|
|
string (REPLACE "-" "+" project_version_safe "${project_version}")
|
|
|
|
# Dependencies
|
|
set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/liberty/cmake)
|
|
include (AddThreads)
|
|
|
|
find_package (PkgConfig REQUIRED)
|
|
pkg_check_modules (libssl REQUIRED libssl libcrypto)
|
|
list (APPEND project_libraries ${libssl_LIBRARIES})
|
|
include_directories (${libssl_INCLUDE_DIRS})
|
|
link_directories (${libssl_LIBRARY_DIRS})
|
|
|
|
if ("${CMAKE_SYSTEM_NAME}" MATCHES "BSD")
|
|
# Need this for SIGWINCH in FreeBSD and OpenBSD respectively;
|
|
# our POSIX version macros make it undefined
|
|
add_definitions (-D__BSD_VISIBLE=1 -D_BSD_SOURCE=1)
|
|
endif ()
|
|
|
|
# -lrt is only for glibc < 2.17
|
|
# -liconv may or may not be a part of libc
|
|
foreach (extra iconv rt)
|
|
find_library (extra_lib_${extra} ${extra})
|
|
if (extra_lib_${extra})
|
|
list (APPEND project_libraries ${extra_lib_${extra}})
|
|
endif ()
|
|
endforeach ()
|
|
|
|
include (CheckCSourceRuns)
|
|
set (CMAKE_REQUIRED_LIBRARIES ${project_libraries})
|
|
get_property (CMAKE_REQUIRED_INCLUDES
|
|
DIRECTORY "${PROJECT_SOURCE_DIR}" PROPERTY INCLUDE_DIRECTORIES)
|
|
CHECK_C_SOURCE_RUNS ("#include <iconv.h>
|
|
int main () { return iconv_open (\"UTF-8//TRANSLIT\", \"ISO-8859-1\")
|
|
== (iconv_t) -1; }" ICONV_ACCEPTS_TRANSLIT)
|
|
|
|
# Dependencies for degesch
|
|
pkg_check_modules (libffi REQUIRED libffi)
|
|
list (APPEND degesch_libraries ${libffi_LIBRARIES})
|
|
include_directories (${libffi_INCLUDE_DIRS})
|
|
link_directories (${libffi_LIBRARY_DIRS})
|
|
|
|
# XXX: other Lua versions may be acceptable, don't know yet
|
|
pkg_search_module (lua lua53 lua5.3 lua-5.3 lua54 lua5.4 lua-5.4 lua>=5.3)
|
|
option (WITH_LUA "Enable support for Lua plugins" ${lua_FOUND})
|
|
|
|
if (WITH_LUA)
|
|
if (NOT lua_FOUND)
|
|
message (FATAL_ERROR "Lua library not found")
|
|
endif ()
|
|
|
|
list (APPEND degesch_libraries ${lua_LIBRARIES})
|
|
include_directories (${lua_INCLUDE_DIRS})
|
|
link_directories (${lua_LIBRARY_DIRS})
|
|
endif ()
|
|
|
|
find_package (Curses)
|
|
pkg_check_modules (ncursesw ncursesw)
|
|
if (ncursesw_FOUND)
|
|
list (APPEND degesch_libraries ${ncursesw_LIBRARIES})
|
|
include_directories (${ncursesw_INCLUDE_DIRS})
|
|
elseif (CURSES_FOUND)
|
|
list (APPEND degesch_libraries ${CURSES_LIBRARY})
|
|
include_directories (${CURSES_INCLUDE_DIR})
|
|
else ()
|
|
message (SEND_ERROR "Curses not found")
|
|
endif ()
|
|
|
|
if ((WANT_READLINE AND WANT_LIBEDIT) OR (NOT WANT_READLINE AND NOT WANT_LIBEDIT))
|
|
message (SEND_ERROR "You have to choose either GNU Readline or libedit")
|
|
elseif (WANT_READLINE)
|
|
# OpenBSD's default readline is too old
|
|
if ("${CMAKE_SYSTEM_NAME}" MATCHES "OpenBSD")
|
|
include_directories (${OPENBSD_LOCALBASE}/include/ereadline)
|
|
list (APPEND degesch_libraries ereadline)
|
|
else ()
|
|
list (APPEND degesch_libraries readline)
|
|
endif ()
|
|
elseif (WANT_LIBEDIT)
|
|
pkg_check_modules (libedit REQUIRED libedit)
|
|
list (APPEND degesch_libraries ${libedit_LIBRARIES})
|
|
include_directories (${libedit_INCLUDE_DIRS})
|
|
endif ()
|
|
|
|
# Generate a configuration file
|
|
set (HAVE_READLINE "${WANT_READLINE}")
|
|
set (HAVE_EDITLINE "${WANT_LIBEDIT}")
|
|
set (HAVE_LUA "${WITH_LUA}")
|
|
|
|
include (GNUInstallDirs)
|
|
configure_file (${PROJECT_SOURCE_DIR}/config.h.in ${PROJECT_BINARY_DIR}/config.h)
|
|
include_directories (${PROJECT_SOURCE_DIR} ${PROJECT_BINARY_DIR})
|
|
|
|
# Generate IRC replies--we need a custom target because of the multiple outputs
|
|
add_custom_command (OUTPUT kike-replies.c kike.msg
|
|
COMMAND ${PROJECT_SOURCE_DIR}/kike-gen-replies.sh
|
|
> kike-replies.c < ${PROJECT_SOURCE_DIR}/kike-replies
|
|
DEPENDS ${PROJECT_SOURCE_DIR}/kike-replies
|
|
COMMENT "Generating files from the list of server numerics")
|
|
add_custom_target (replies DEPENDS ${PROJECT_BINARY_DIR}/kike-replies.c)
|
|
|
|
# Build
|
|
foreach (name zyklonb degesch kike)
|
|
add_executable (${name} ${name}.c ${PROJECT_BINARY_DIR}/config.h)
|
|
target_link_libraries (${name} ${project_libraries})
|
|
add_threads (${name})
|
|
endforeach ()
|
|
|
|
add_dependencies (kike replies)
|
|
add_dependencies (degesch replies)
|
|
target_link_libraries (degesch ${degesch_libraries})
|
|
|
|
# Tests
|
|
include (CTest)
|
|
if (BUILD_TESTING)
|
|
add_executable (test-degesch $<TARGET_PROPERTY:degesch,SOURCES>)
|
|
set_target_properties (test-degesch PROPERTIES COMPILE_DEFINITIONS TESTING)
|
|
target_link_libraries (test-degesch $<TARGET_PROPERTY:degesch,LINK_LIBRARIES>)
|
|
add_threads (test-degesch)
|
|
add_dependencies (test-degesch replies)
|
|
|
|
add_test (NAME test-degesch COMMAND test-degesch)
|
|
add_test (NAME custom-static-analysis
|
|
COMMAND ${PROJECT_SOURCE_DIR}/test-static)
|
|
endif ()
|
|
|
|
# Various clang-based diagnostics, loads of fake positives and spam
|
|
file (GLOB clang_tidy_sources *.c)
|
|
set (clang_tidy_checks misc-* readability-*
|
|
-readability-braces-around-statements
|
|
-readability-named-parameter)
|
|
string (REPLACE ";" "," clang_tidy_checks "${clang_tidy_checks}")
|
|
|
|
set (CMAKE_EXPORT_COMPILE_COMMANDS ON)
|
|
add_custom_target (clang-tidy
|
|
COMMAND clang-tidy -p ${PROJECT_BINARY_DIR} -checks=${clang_tidy_checks}
|
|
${clang_tidy_sources} 1>&2
|
|
USES_TERMINAL
|
|
WORKING_DIRECTORY ${PROJECT_SOURCE_DIR})
|
|
|
|
# Installation
|
|
install (TARGETS zyklonb degesch kike DESTINATION ${CMAKE_INSTALL_BINDIR})
|
|
install (FILES LICENSE DESTINATION ${CMAKE_INSTALL_DOCDIR})
|
|
# XXX: our defaults for XDG_DATA_DIRS expect /usr/local/shore or /usr/share
|
|
install (DIRECTORY plugins/zyklonb/
|
|
DESTINATION ${CMAKE_INSTALL_DATADIR}/zyklonb/plugins USE_SOURCE_PERMISSIONS)
|
|
install (DIRECTORY plugins/degesch/
|
|
DESTINATION ${CMAKE_INSTALL_DATADIR}/degesch/plugins)
|
|
|
|
# Generate documentation from text markup
|
|
find_program (ASCIIDOCTOR_EXECUTABLE asciidoctor)
|
|
if (NOT ASCIIDOCTOR_EXECUTABLE)
|
|
message (FATAL_ERROR "asciidoctor not found")
|
|
endif ()
|
|
|
|
foreach (page zyklonb degesch kike)
|
|
set (page_output "${PROJECT_BINARY_DIR}/${page}.1")
|
|
list (APPEND project_MAN_PAGES "${page_output}")
|
|
add_custom_command (OUTPUT ${page_output}
|
|
COMMAND ${ASCIIDOCTOR_EXECUTABLE} -b manpage
|
|
-a release-version=${project_version}
|
|
"${PROJECT_SOURCE_DIR}/${page}.adoc"
|
|
-o "${page_output}"
|
|
DEPENDS ${page}.adoc
|
|
COMMENT "Generating man page for ${page}" VERBATIM)
|
|
endforeach ()
|
|
|
|
add_custom_target (docs ALL DEPENDS ${project_MAN_PAGES})
|
|
|
|
foreach (page ${project_MAN_PAGES})
|
|
string (REGEX MATCH "\\.([0-9])$" manpage_suffix "${page}")
|
|
install (FILES "${page}"
|
|
DESTINATION "${CMAKE_INSTALL_MANDIR}/man${CMAKE_MATCH_1}")
|
|
endforeach ()
|
|
|
|
# CPack
|
|
set (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Unethical IRC client, daemon and bot")
|
|
set (CPACK_PACKAGE_VERSION "${project_version_safe}")
|
|
set (CPACK_PACKAGE_VENDOR "Premysl Eric Janouch")
|
|
set (CPACK_PACKAGE_CONTACT "Přemysl Eric Janouch <p@janouch.name>")
|
|
set (CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/LICENSE")
|
|
|
|
set (CPACK_GENERATOR "TGZ;ZIP")
|
|
set (CPACK_PACKAGE_FILE_NAME
|
|
"${PROJECT_NAME}-${project_version_safe}-${CMAKE_SYSTEM_NAME}-${CMAKE_SYSTEM_PROCESSOR}")
|
|
set (CPACK_PACKAGE_INSTALL_DIRECTORY "${PROJECT_NAME}-${project_version_safe}")
|
|
|
|
set (CPACK_SOURCE_GENERATOR "TGZ;ZIP")
|
|
set (CPACK_SOURCE_IGNORE_FILES "/\\\\.git;/build;/CMakeLists.txt.user")
|
|
set (CPACK_SOURCE_PACKAGE_FILE_NAME "${PROJECT_NAME}-${project_version_safe}")
|
|
|
|
set (CPACK_SET_DESTDIR TRUE)
|
|
include (CPack)
|