189 lines
6.9 KiB
CMake
189 lines
6.9 KiB
CMake
project (uirc3 C)
|
|
cmake_minimum_required (VERSION 2.8.5)
|
|
|
|
# Options
|
|
option (WANT_READLINE "Use GNU Readline for the UI (better)" ON)
|
|
option (WANT_LIBEDIT "Use BSD libedit for the UI" OFF)
|
|
|
|
# Moar warnings
|
|
if ("${CMAKE_C_COMPILER_ID}" MATCHES "GNU" OR CMAKE_COMPILER_IS_GNUC)
|
|
# -Wunused-function is pretty annoying here, as everything is static
|
|
set (CMAKE_C_FLAGS "-std=c99 -Wall -Wextra -Wno-unused-function")
|
|
endif ("${CMAKE_C_COMPILER_ID}" MATCHES "GNU" OR CMAKE_COMPILER_IS_GNUC)
|
|
|
|
# Version
|
|
set (project_VERSION_MAJOR "0")
|
|
set (project_VERSION_MINOR "9")
|
|
set (project_VERSION_PATCH "1")
|
|
|
|
set (project_VERSION "${project_VERSION_MAJOR}")
|
|
set (project_VERSION "${project_VERSION}.${project_VERSION_MINOR}")
|
|
set (project_VERSION "${project_VERSION}.${project_VERSION_PATCH}")
|
|
|
|
# Dependencies
|
|
find_package (Curses)
|
|
find_package (PkgConfig REQUIRED)
|
|
pkg_check_modules (libssl REQUIRED libssl libcrypto)
|
|
pkg_check_modules (ncursesw ncursesw)
|
|
|
|
if ("${CMAKE_SYSTEM_NAME}" MATCHES "BSD")
|
|
include_directories(/usr/local/include)
|
|
link_directories(/usr/local/lib)
|
|
# Need this for SIGWINCH in FreeBSD and OpenBSD respectively;
|
|
# our POSIX version macros make it undefined
|
|
add_definitions (-D__BSD_VISIBLE=1 -D_BSD_SOURCE=1)
|
|
endif ("${CMAKE_SYSTEM_NAME}" MATCHES "BSD")
|
|
|
|
list (APPEND project_libraries ${libssl_LIBRARIES})
|
|
include_directories (${libssl_INCLUDE_DIRS})
|
|
link_directories (${libssl_LIBRARY_DIRS})
|
|
|
|
# FIXME: other Lua versions may be acceptable, don't know yet
|
|
pkg_search_module (lua lua5.3 lua-5.3 lua>=5.3)
|
|
option (WITH_LUA "Enable experimental support for Lua plugins" ${lua_FOUND})
|
|
|
|
if (WITH_LUA)
|
|
if (NOT lua_FOUND)
|
|
message (FATAL_ERROR "Lua library not found")
|
|
endif (NOT lua_FOUND)
|
|
|
|
list (APPEND project_libraries ${lua_LIBRARIES})
|
|
include_directories (${lua_INCLUDE_DIRS})
|
|
link_directories (${lua_LIBRARY_DIRS})
|
|
endif (WITH_LUA)
|
|
|
|
# -lpthread is only there for debugging (gdb & errno)
|
|
# -lrt is only for glibc < 2.17
|
|
# -liconv may or may not be a part of libc
|
|
foreach (extra iconv rt pthread)
|
|
find_library (extra_lib_${extra} ${extra})
|
|
if (extra_lib_${extra})
|
|
list (APPEND project_libraries ${extra})
|
|
endif (extra_lib_${extra})
|
|
endforeach (extra)
|
|
|
|
if (ncursesw_FOUND)
|
|
list (APPEND project_libraries ${ncursesw_LIBRARIES})
|
|
include_directories (${ncursesw_INCLUDE_DIRS})
|
|
elseif (CURSES_FOUND)
|
|
list (APPEND project_libraries ${CURSES_LIBRARY})
|
|
include_directories (${CURSES_INCLUDE_DIR})
|
|
else (CURSES_FOUND)
|
|
message (SEND_ERROR "Curses not found")
|
|
endif (ncursesw_FOUND)
|
|
|
|
if ((WANT_READLINE AND WANT_LIBEDIT) OR (NOT WANT_READLINE AND NOT WANT_LIBEDIT))
|
|
message (SEND_ERROR "You have to choose either GNU Readline or libedit")
|
|
elseif (WANT_READLINE)
|
|
# OpenBSD's default readline is too old
|
|
if ("${CMAKE_SYSTEM_NAME}" MATCHES "OpenBSD")
|
|
include_directories (/usr/local/include/ereadline)
|
|
list (APPEND project_libraries ereadline)
|
|
else ("${CMAKE_SYSTEM_NAME}" MATCHES "OpenBSD")
|
|
list (APPEND project_libraries readline)
|
|
endif ("${CMAKE_SYSTEM_NAME}" MATCHES "OpenBSD")
|
|
elseif (WANT_LIBEDIT)
|
|
pkg_check_modules (libedit REQUIRED libedit)
|
|
list (APPEND project_libraries ${libedit_LIBRARIES})
|
|
include_directories (${libedit_INCLUDE_DIRS})
|
|
endif ((WANT_READLINE AND WANT_LIBEDIT) OR (NOT WANT_READLINE AND NOT WANT_LIBEDIT))
|
|
|
|
# Generate a configuration file
|
|
set (HAVE_READLINE "${WANT_READLINE}")
|
|
set (HAVE_EDITLINE "${WANT_LIBEDIT}")
|
|
set (HAVE_LUA "${WITH_LUA}")
|
|
|
|
include (GNUInstallDirs)
|
|
# ZyklonB is currently an odd duck but degesch follows normal XDG rules
|
|
set (zyklonb_plugin_dir ${CMAKE_INSTALL_LIBDIR}/zyklonb/plugins)
|
|
configure_file (${PROJECT_SOURCE_DIR}/config.h.in ${PROJECT_BINARY_DIR}/config.h)
|
|
include_directories (${PROJECT_SOURCE_DIR} ${PROJECT_BINARY_DIR})
|
|
|
|
# Project source files
|
|
set (common_sources)
|
|
set (common_headers ${PROJECT_BINARY_DIR}/config.h)
|
|
|
|
add_custom_command (OUTPUT kike-replies.c kike.msg
|
|
COMMAND ${PROJECT_SOURCE_DIR}/kike-gen-replies.sh
|
|
> kike-replies.c < ${PROJECT_SOURCE_DIR}/kike-replies
|
|
DEPENDS ${PROJECT_SOURCE_DIR}/kike-replies
|
|
COMMENT "Generating files from the list of server numerics")
|
|
set_source_files_properties (${PROJECT_BINARY_DIR}/kike-replies.c
|
|
PROPERTIES HEADER_FILE_ONLY TRUE)
|
|
|
|
# Build
|
|
add_executable (zyklonb zyklonb.c ${common_sources} ${common_headers})
|
|
target_link_libraries (zyklonb ${project_libraries})
|
|
|
|
add_executable (degesch degesch.c kike-replies.c
|
|
${common_sources} ${common_headers})
|
|
target_link_libraries (degesch ${project_libraries})
|
|
|
|
add_executable (kike kike.c kike-replies.c ${common_sources} ${common_headers})
|
|
target_link_libraries (kike ${project_libraries})
|
|
|
|
# Various clang-based diagnostics, loads of fake positives and spam
|
|
file (GLOB clang_tidy_sources *.c)
|
|
set (clang_tidy_checks misc-* readability-*
|
|
-readability-braces-around-statements
|
|
-readability-named-parameter)
|
|
string (REPLACE ";" "," clang_tidy_checks "${clang_tidy_checks}")
|
|
|
|
set (CMAKE_EXPORT_COMPILE_COMMANDS ON)
|
|
add_custom_target (clang-tidy
|
|
COMMAND clang-tidy -p ${PROJECT_BINARY_DIR} -checks=${clang_tidy_checks}
|
|
${clang_tidy_sources} 1>&2
|
|
USES_TERMINAL
|
|
WORKING_DIRECTORY ${PROJECT_SOURCE_DIR})
|
|
|
|
# Installation
|
|
install (TARGETS zyklonb degesch kike DESTINATION ${CMAKE_INSTALL_BINDIR})
|
|
install (FILES LICENSE DESTINATION ${CMAKE_INSTALL_DOCDIR})
|
|
install (DIRECTORY plugins/zyklonb/
|
|
DESTINATION ${zyklonb_plugin_dir} USE_SOURCE_PERMISSIONS)
|
|
install (DIRECTORY plugins/degesch/
|
|
DESTINATION ${CMAKE_INSTALL_DATADIR}/degesch/plugins)
|
|
|
|
# Generate documentation from program help
|
|
find_program (HELP2MAN_EXECUTABLE help2man)
|
|
if (NOT HELP2MAN_EXECUTABLE)
|
|
message (FATAL_ERROR "help2man not found")
|
|
endif (NOT HELP2MAN_EXECUTABLE)
|
|
|
|
foreach (page zyklonb degesch kike)
|
|
set (page_output "${PROJECT_BINARY_DIR}/${page}.1")
|
|
list (APPEND project_MAN_PAGES "${page_output}")
|
|
add_custom_command (OUTPUT ${page_output}
|
|
COMMAND ${HELP2MAN_EXECUTABLE} -N
|
|
"${PROJECT_BINARY_DIR}/${page}" -o ${page_output}
|
|
DEPENDS ${page}
|
|
COMMENT "Generating man page for ${page}" VERBATIM)
|
|
endforeach (page)
|
|
|
|
add_custom_target (docs ALL DEPENDS ${project_MAN_PAGES})
|
|
|
|
foreach (page ${project_MAN_PAGES})
|
|
string (REGEX MATCH "\\.([0-9])" manpage_suffix "${page}")
|
|
install (FILES "${page}"
|
|
DESTINATION "${CMAKE_INSTALL_MANDIR}/man${CMAKE_MATCH_1}")
|
|
endforeach (page)
|
|
|
|
# CPack
|
|
set (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Experimental IRC client, daemon and bot")
|
|
set (CPACK_PACKAGE_VERSION ${project_VERSION})
|
|
set (CPACK_PACKAGE_VENDOR "Premysl Janouch")
|
|
set (CPACK_PACKAGE_CONTACT "Přemysl Janouch <p.janouch@gmail.com>")
|
|
set (CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/LICENSE")
|
|
|
|
set (CPACK_GENERATOR "TGZ;ZIP")
|
|
set (CPACK_PACKAGE_FILE_NAME
|
|
"${PROJECT_NAME}-${project_VERSION}-${CMAKE_SYSTEM_NAME}-${CMAKE_SYSTEM_PROCESSOR}")
|
|
set (CPACK_PACKAGE_INSTALL_DIRECTORY "${PROJECT_NAME}-${project_VERSION}")
|
|
|
|
set (CPACK_SOURCE_GENERATOR "TGZ;ZIP")
|
|
set (CPACK_SOURCE_IGNORE_FILES "/\\\\.git;/build;/CMakeLists.txt.user")
|
|
set (CPACK_SOURCE_PACKAGE_FILE_NAME "${PROJECT_NAME}-${project_VERSION}")
|
|
|
|
set (CPACK_SET_DESTDIR TRUE)
|
|
include (CPack)
|